blob: 423380b17f4274d564179ea9c815e9757f42e5e9 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
|
@ECHO OFF
SETLOCAL
SET EXITCODE=0
SET clean=false
SET addon=
SETLOCAL EnableDelayedExpansion
FOR %%b IN (%*) DO (
IF %%b == clean (
SET clean=true
) ELSE (
SET addon=!addon! %%b
)
)
SETLOCAL DisableDelayedExpansion
rem set Visual C++ build environment
call "%VS140COMNTOOLS%..\..\VC\bin\amd64_x86\vcvarsamd64_x86.bat" || call "%VS140COMNTOOLS%..\..\VC\bin\vcvars32.bat"
SET WORKDIR=%WORKSPACE%
IF "%WORKDIR%" == "" (
SET WORKDIR=%CD%\..\..
)
rem setup some paths that we need later
SET CUR_PATH=%CD%
SET BASE_PATH=%WORKDIR%\cmake
SET SCRIPTS_PATH=%BASE_PATH%\scripts\windows
SET ADDONS_PATH=%BASE_PATH%\addons
SET ADDON_DEPENDS_PATH=%ADDONS_PATH%\output
SET ADDONS_BUILD_PATH=%ADDONS_PATH%\build
SET ADDONS_DEFINITION_PATH=%ADDONS_PATH%\addons
SET ERRORFILE=%ADDONS_PATH%\make-addons.error
IF %clean% == true (
rem remove the build directory if it exists
IF EXIST "%ADDONS_BUILD_PATH%" (
RMDIR "%ADDONS_BUILD_PATH%" /S /Q > NUL
)
rem remove the build directory if it exists
IF EXIST "%ADDON_DEPENDS_PATH%" (
RMDIR "%ADDON_DEPENDS_PATH%" /S /Q > NUL
)
GOTO END
)
rem create the depends directory
IF NOT EXIST "%ADDON_DEPENDS_PATH%" MKDIR "%ADDON_DEPENDS_PATH%"
rem create the build directory
IF NOT EXIST "%ADDONS_BUILD_PATH%" MKDIR "%ADDONS_BUILD_PATH%"
rem go into the build directory
CD "%ADDONS_BUILD_PATH%"
ECHO --------------------------------------------------
ECHO Preparing addons development environment
ECHO --------------------------------------------------
SET ADDONS_TO_BUILD=
IF "%addon%" NEQ "" (
SET ADDONS_TO_BUILD=%addon%
) ELSE (
SETLOCAL EnableDelayedExpansion
FOR /D %%a IN (%ADDONS_DEFINITION_PATH%\*) DO (
SET ADDONS_TO_BUILD=!ADDONS_TO_BUILD! %%~nxa
)
SETLOCAL DisableDelayedExpansion
)
rem execute cmake to generate Visual Studio 12 project files
cmake "%ADDONS_PATH%" -G "Visual Studio 14" ^
-DCMAKE_BUILD_TYPE=Release ^
-DCMAKE_USER_MAKE_RULES_OVERRIDE="%SCRIPTS_PATH%/CFlagOverrides.cmake" ^
-DCMAKE_USER_MAKE_RULES_OVERRIDE_CXX="%SCRIPTS_PATH%/CXXFlagOverrides.cmake" ^
-DCMAKE_INSTALL_PREFIX=%WORKDIR%\addons ^
-DCMAKE_SOURCE_DIR=%WORKDIR% ^
-DBUILD_DIR=%ADDONS_BUILD_PATH% ^
-DADDON_DEPENDS_PATH=%ADDON_DEPENDS_PATH% ^
-DPACKAGE_ZIP=ON ^
-DADDONS_TO_BUILD="%ADDONS_TO_BUILD%"
IF ERRORLEVEL 1 (
ECHO cmake error level: %ERRORLEVEL% > %ERRORFILE%
GOTO ERROR
)
rem everything was fine
GOTO END
:ERROR
rem something went wrong
ECHO Failed to prepare addons development environment
ECHO See %ERRORFILE% for more details
SET EXITCODE=1
:END
rem go back to the original directory
cd %CUR_PATH%
rem exit the script with the defined exitcode
EXIT /B %EXITCODE%
|
