blob: efad84a9cfba39f11d179ba45f15d459ae3d9298 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
|
@ECHO OFF
SETLOCAL
SET EXITCODE=0
SET install=false
SET clean=false
SET package=false
SET addon=
SETLOCAL EnableDelayedExpansion
FOR %%b IN (%*) DO (
IF %%b == install (
SET install=true
) ELSE ( IF %%b == clean (
SET clean=true
) ELSE ( IF %%b == package (
SET package=true
) ELSE (
SET addon=!addon! %%b
)))
)
SETLOCAL DisableDelayedExpansion
rem set Visual C++ build environment
call "%VS140COMNTOOLS%..\..\VC\bin\vcvars32.bat"
SET WORKDIR=%base_dir%
IF "%WORKDIR%" == "" (
rem resolve the relative path
SETLOCAL EnableDelayedExpansion
PUSHD ..\..\..
SET WORKDIR=!CD!
POPD
SETLOCAL DisableDelayedExpansion
)
rem setup some paths that we need later
SET CUR_PATH=%CD%
SET BASE_PATH=%WORKDIR%\project\cmake
SET SCRIPTS_PATH=%BASE_PATH%\scripts\windows
SET ADDONS_PATH=%BASE_PATH%\addons
SET ADDON_DEPENDS_PATH=%ADDONS_PATH%\output
SET ADDONS_BUILD_PATH=%ADDONS_PATH%\build
SET ADDONS_DEFINITION_PATH=%ADDONS_PATH%\addons
SET ADDONS_SUCCESS_FILE=%ADDONS_PATH%\.success
SET ADDONS_FAILURE_FILE=%ADDONS_PATH%\.failure
SET ERRORFILE=%ADDONS_PATH%\make-addons.error
rem remove the success and failure files from a previous build
DEL /F %ADDONS_SUCCESS_FILE% > NUL 2>&1
DEL /F %ADDONS_FAILURE_FILE% > NUL 2>&1
IF %clean% == true (
rem remove the build directory if it exists
IF EXIST "%ADDONS_BUILD_PATH%" (
ECHO Cleaning build directory...
RMDIR "%ADDONS_BUILD_PATH%" /S /Q > NUL
)
rem remove the build directory if it exists
IF EXIST "%ADDON_DEPENDS_PATH%" (
ECHO Cleaning dependencies...
RMDIR "%ADDON_DEPENDS_PATH%" /S /Q > NUL
)
GOTO END
)
rem create the depends directory
IF NOT EXIST "%ADDON_DEPENDS_PATH%" MKDIR "%ADDON_DEPENDS_PATH%"
rem create the build directory
IF NOT EXIST "%ADDONS_BUILD_PATH%" MKDIR "%ADDONS_BUILD_PATH%"
rem go into the build directory
CD "%ADDONS_BUILD_PATH%"
rem determine the proper install path for the built addons
IF %install% == true (
SET ADDONS_INSTALL_PATH=%WORKSPACE%\addons
) ELSE (
SET ADDONS_INSTALL_PATH=%WORKDIR%\project\Win32BuildSetup\BUILD_WIN32\addons
)
ECHO --------------------------------------------------
ECHO Building addons
ECHO --------------------------------------------------
SET ADDONS_TO_BUILD=
IF "%addon%" NEQ "" (
SET ADDONS_TO_BUILD=%addon%
) ELSE (
SETLOCAL EnableDelayedExpansion
FOR /D %%a IN (%ADDONS_DEFINITION_PATH%\*) DO (
SET ADDONS_TO_BUILD=!ADDONS_TO_BUILD! %%~nxa
)
SETLOCAL DisableDelayedExpansion
)
rem execute cmake to generate makefiles processable by nmake
cmake "%ADDONS_PATH%" -G "NMake Makefiles" ^
-DCMAKE_BUILD_TYPE=Release ^
-DCMAKE_USER_MAKE_RULES_OVERRIDE="%SCRIPTS_PATH%/CFlagOverrides.cmake" ^
-DCMAKE_USER_MAKE_RULES_OVERRIDE_CXX="%SCRIPTS_PATH%/CXXFlagOverrides.cmake" ^
-DCMAKE_INSTALL_PREFIX=%ADDONS_INSTALL_PATH% ^
-DCORE_SOURCE_DIR=%WORKDIR% ^
-DBUILD_DIR=%ADDONS_BUILD_PATH% ^
-DDEPENDS_PATH=%ADDON_DEPENDS_PATH% ^
-DPACKAGE_ZIP=ON ^
-DADDONS_TO_BUILD="%ADDONS_TO_BUILD%"
IF ERRORLEVEL 1 (
ECHO cmake error level: %ERRORLEVEL% > %ERRORFILE%
GOTO ERROR
)
rem get the list of addons that can actually be built
SET ADDONS_TO_MAKE=
SETLOCAL EnableDelayedExpansion
FOR /f "delims=" %%i IN ('nmake supported_addons') DO (
SET line="%%i"
SET addons=!line:ALL_ADDONS_BUILDING=!
IF NOT "!addons!" == "!line!" (
SET ADDONS_TO_MAKE=!addons:~3,-1!
)
)
SETLOCAL DisableDelayedExpansion
rem loop over all addons to build
FOR %%a IN (%ADDONS_TO_MAKE%) DO (
ECHO Building %%a...
rem execute nmake to build the addons
nmake %%a
IF ERRORLEVEL 1 (
ECHO nmake %%a error level: %ERRORLEVEL% > %ERRORFILE%
ECHO %%a >> %ADDONS_FAILURE_FILE%
) ELSE (
if %package% == true (
nmake package-%%a
IF ERRORLEVEL 1 (
ECHO nmake package-%%a error level: %ERRORLEVEL% > %ERRORFILE%
ECHO %%a >> %ADDONS_FAILURE_FILE%
) ELSE (
ECHO %%a >> %ADDONS_SUCCESS_FILE%
)
) ELSE (
ECHO %%a >> %ADDONS_SUCCESS_FILE%
)
)
)
rem everything was fine
GOTO END
:ERROR
rem something went wrong
FOR %%a IN (%ADDONS_TO_BUILD%) DO (
ECHO %%a >> %ADDONS_FAILURE_FILE%
)
ECHO Failed to build addons
ECHO See %ERRORFILE% for more details
SET EXITCODE=1
:END
rem go back to the original directory
cd %CUR_PATH%
rem exit the script with the defined exitcode
EXIT /B %EXITCODE%
|
