Merge #21182: build: remove mostly pointless BOOST_PROCESS macro

7bf04e358a6550ac9851f1b2d87795927fc5ff4b build: remove mostly pointless BOOST_PROCESS macro (fanquake)

Pull request description:

  Performing a series of link checks for a Boost component that is
  header-only doesn't make much sense, and currently means we just have
  another confusing Boost macro in our tree. I'm not sure why this was
  originally done this way; maybe Sjors or luke-jr can elaborate (#15382 (929cda5470f98d1ef85c05b1cad4e2fb9227e3b0))?

  The macro also has the side-effect of producing confusing error
  messages. i.e in #20744, the CI is currently failing with:
  ```bash
  checking for boostlib >= 1.58.0 (105800) lib path in "/tmp/cirrus-ci-build/depends/x86_64-pc-linux-gnu/lib"... yes
  checking for boostlib >= 1.58.0 (105800)... yes
  checking whether the Boost::Process library is available... yes
  configure: error: Could not find a version of the Boost::Process library!
  ```

  This isn't useful, given there is no such thing as a `Boost::Process` library.

  This PR just removes the macro entirely, but maintains a `--with-boost-process`
  (defaulting to off), flag to configure. Hopefully this will also be
  removed, in favour of `--enable/disable-external-signer` if/when #16546
  is merged.

ACKs for top commit:
  laanwj:
    ACK 7bf04e358a6550ac9851f1b2d87795927fc5ff4b

Tree-SHA512: b270a0250f32df2078f986c165b8977967d8c06df80bf2773f3442f74b395a3bfa6544af1024d9b6524d90d47a0f6304194b3aced0e2ecb88e75916da945ccb6

2 files changed, 15 insertions, 124 deletions

diff --git a/build-aux/m4/ax_boost_process.m4 b/build-aux/m4/ax_boost_process.m4
deleted file mode 100644
index 5d20e67464..0000000000
--- a/build-aux/m4/ax_boost_process.m4
+++ /dev/null
@@ -1,121 +0,0 @@
-# ===========================================================================
-#     https://www.gnu.org/software/autoconf-archive/ax_boost_process.html
-# ===========================================================================
-#
-# SYNOPSIS
-#
-#   AX_BOOST_PROCESS
-#
-# DESCRIPTION
-#
-#   Test for Process library from the Boost C++ libraries. The macro
-#   requires a preceding call to AX_BOOST_BASE. Further documentation is
-#   available at <http://randspringer.de/boost/index.html>.
-#
-#   This macro calls:
-#
-#     AC_SUBST(BOOST_PROCESS_LIB)
-#
-#   And sets:
-#
-#     HAVE_BOOST_PROCESS
-#
-# LICENSE
-#
-#   Copyright (c) 2008 Thomas Porschberg <thomas@randspringer.de>
-#   Copyright (c) 2008 Michael Tindal
-#   Copyright (c) 2008 Daniel Casimiro <dan.casimiro@gmail.com>
-#
-#   Copying and distribution of this file, with or without modification, are
-#   permitted in any medium without royalty provided the copyright notice
-#   and this notice are preserved. This file is offered as-is, without any
-#   warranty.
-
-#serial 2
-
-AC_DEFUN([AX_BOOST_PROCESS],
-[
-	AC_ARG_WITH([boost-process],
-	AS_HELP_STRING([--with-boost-process@<:@=special-lib@:>@],
-                   [use the Process library from boost - it is possible to specify a certain library for the linker
-                        e.g. --with-boost-process=boost_process-gcc-mt ]),
-        [
-        if test "$withval" = "no"; then
-			want_boost_process="no"
-        elif test "$withval" = "yes"; then
-            want_boost_process="yes"
-            ax_boost_user_process_lib=""
-        else
-		    want_boost_process="yes"
-		ax_boost_user_process_lib="$withval"
-		fi
-        ],
-        [want_boost_process="yes"]
-	)
-
-	if test "x$want_boost_process" = "xyes"; then
-        AC_REQUIRE([AC_PROG_CC])
-        AC_REQUIRE([AC_CANONICAL_BUILD])
-		CPPFLAGS_SAVED="$CPPFLAGS"
-		CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
-		export CPPFLAGS
-
-		LDFLAGS_SAVED="$LDFLAGS"
-		LDFLAGS="$LDFLAGS $BOOST_LDFLAGS"
-		export LDFLAGS
-
-        AC_CACHE_CHECK(whether the Boost::Process library is available,
-					   ax_cv_boost_process,
-        [AC_LANG_PUSH([C++])
-			 CXXFLAGS_SAVE=$CXXFLAGS
-			 CXXFLAGS=
-
-             AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[@%:@include <boost/process.hpp>]],
-                [[boost::process::child* child = new boost::process::child; delete child;]])],
-                ax_cv_boost_process=yes, ax_cv_boost_process=no)
-			 CXXFLAGS=$CXXFLAGS_SAVE
-             AC_LANG_POP([C++])
-		])
-		if test "x$ax_cv_boost_process" = "xyes"; then
-			AC_SUBST(BOOST_CPPFLAGS)
-
-			AC_DEFINE(HAVE_BOOST_PROCESS,,[define if the Boost::Process library is available])
-            BOOSTLIBDIR=`echo $BOOST_LDFLAGS | sed -e 's/@<:@^\/@:>@*//'`
-
-			LDFLAGS_SAVE=$LDFLAGS
-            if test "x$ax_boost_user_process_lib" = "x"; then
-                for libextension in `ls -r $BOOSTLIBDIR/libboost_process* 2>/dev/null | sed 's,.*/lib,,' | sed 's,\..*,,'` ; do
-                     ax_lib=${libextension}
-				    AC_CHECK_LIB($ax_lib, exit,
-                                 [BOOST_PROCESS_LIB="-l$ax_lib"; AC_SUBST(BOOST_PROCESS_LIB) link_process="yes"; break],
-                                 [link_process="no"])
-				done
-                if test "x$link_process" != "xyes"; then
-                for libextension in `ls -r $BOOSTLIBDIR/boost_process* 2>/dev/null | sed 's,.*/,,' | sed -e 's,\..*,,'` ; do
-                     ax_lib=${libextension}
-				    AC_CHECK_LIB($ax_lib, exit,
-                                 [BOOST_PROCESS_LIB="-l$ax_lib"; AC_SUBST(BOOST_PROCESS_LIB) link_process="yes"; break],
-                                 [link_process="no"])
-				done
-                fi
-
-            else
-               for ax_lib in $ax_boost_user_process_lib boost_process-$ax_boost_user_process_lib; do
-				      AC_CHECK_LIB($ax_lib, exit,
-                                   [BOOST_PROCESS_LIB="-l$ax_lib"; AC_SUBST(BOOST_PROCESS_LIB) link_process="yes"; break],
-                                   [link_process="no"])
-                  done
-
-            fi
-            if test "x$ax_lib" = "x"; then
-                AC_MSG_ERROR(Could not find a version of the Boost::Process library!)
-            fi
-			if test "x$link_process" = "xno"; then
-				AC_MSG_ERROR(Could not link against $ax_lib !)
-			fi
-		fi
-
-		CPPFLAGS="$CPPFLAGS_SAVED"
-	LDFLAGS="$LDFLAGS_SAVED"
-	fi
-])
diff --git a/configure.ac b/configure.ac
index 62f1c308b7..0b2721673f 100644
--- a/configure.ac
+++ b/configure.ac
@@ -338,6 +338,11 @@ AC_ARG_ENABLE([werror],
     [enable_werror=$enableval],
     [enable_werror=no])
 
+AC_ARG_WITH([boost-process],
+    [AS_HELP_STRING([--with-boost-process],[Opt in to using Boost Process (default is no)])],
+    [boost_process=$withval],
+    [boost_process=no])
+
 AC_LANG_PUSH([C++])
 
 dnl Check for a flag to turn compiler warnings into errors. This is helpful for checks which may
@@ -1388,8 +1393,15 @@ fi
 AX_BOOST_SYSTEM
 AX_BOOST_FILESYSTEM
 
-dnl Opt-in to boost-process
-AS_IF([ test x$with_boost_process != x ], [ AX_BOOST_PROCESS ], [ ax_cv_boost_process=no ] )
+dnl Opt-in to Boost Process
+if test "x$boost_process" != xno; then
+AC_MSG_CHECKING(for Boost Process)
+AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <boost/process.hpp>]],
+ [[ boost::process::child* child = new boost::process::child; delete child; ]])],
+ [ AC_MSG_RESULT(yes); AC_DEFINE([HAVE_BOOST_PROCESS],,[define if Boost::Process is available])],
+ [ AC_MSG_ERROR([Boost::Process is not available!])]
+)
+fi
 
 if test x$suppress_external_warnings != xno; then
     BOOST_CPPFLAGS=SUPPRESS_WARNINGS($BOOST_CPPFLAGS)
@@ -1876,7 +1888,7 @@ esac
 
 echo
 echo "Options used to compile and link:"
-echo "  boost process = $ax_cv_boost_process"
+echo "  boost process = $with_boost_process"
 echo "  multiprocess  = $build_multiprocess"
 echo "  with libs     = $build_bitcoin_libs"
 echo "  with wallet   = $enable_wallet"